{ config, pkgs, lib, ... }:

{
  imports = [
    ./services/gitea.nix
    ./services/hydra.nix
    ./services/minecraft.nix
    ./services/nextcloud.nix
    ./services/webserver.nix
    ./ids.nix
  ];

  nix = {
    # Enable flakes
    package = pkgs.nixFlakes;
    extraOptions = ''
      experimental-features = nix-command flakes
    '';

    # Enable remote builds from tlater
    trustedUsers = [ "@wheel" ];
  };

  networking = {
    hostName = "tlaternet";

    usePredictableInterfaceNames = false;
    useDHCP = false;
    interfaces.eth0.useDHCP = true;

    firewall.allowedTCPPorts = [ 80 443 2222 2221 25565 ];
  };

  time.timeZone = "Europe/London";

  users.users.tlater = {
    isNormalUser = true;
    extraGroups = [ "wheel" ];
    openssh.authorizedKeys.keyFiles = [ ../keys/tlater.pub ];
  };

  services.openssh = {
    enable = true;
    allowSFTP = false;
    passwordAuthentication = false;
    permitRootLogin = "no";
    ports = [ 2222 ];
    startWhenNeeded = true;
  };

  services.nginx = {
    enable = true;
    recommendedTlsSettings = true;
    recommendedOptimisation = true;
    recommendedGzipSettings = true;
    recommendedProxySettings = true;
    clientMaxBodySize = "10G";
    domain = "tlater.net";

    virtualHosts = let
      host = port: extra:
        lib.recursiveUpdate {
          forceSSL = true;
          enableACME = true;
          locations."/" = { proxyPass = "http://127.0.0.1:${toString port}"; };
        } extra;
      domain = config.services.nginx.domain;
    in {
      "${domain}" = host 3002 { serverAliases = [ "www.${domain}" ]; };
      "gitea.${domain}" = host 3000 { };
      "nextcloud.${domain}" = host 3001 { };
      "hydra.${domain}" = host config.services.hydra.port { };
    };
  };

  security.acme = {
    email = "tm@tlater.net";
    acceptTerms = true;
  };

  virtualisation.oci-containers.backend = "podman";

  system.stateVersion = "20.09";
}