{ self, ... }:
{
  # Systems on which to make dev utilities runnable; anything
  # NixOS-related encodes its own system.
  systems = [ "x86_64-linux" ];

  perSystem =
    {
      inputs',
      self',
      pkgs,
      lib,
      ...
    }:
    {
      apps = {
        default = self'.apps.runVm;

        runVm = {
          type = "app";
          program = lib.getExe self.nixosConfigurations.hetzner-1.config.system.build.vm;
          meta.description = "Run the test VM";
        };
      };

      devShells = {
        default = pkgs.mkShell {
          sopsPGPKeyDirs = [
            "./keys/hosts/"
            "./keys/users/"
          ];

          packages = lib.attrValues {
            inherit (inputs'.sops-nix.packages) sops-import-keys-hook sops-init-gpg-key;
            inherit (pkgs) deploy-rs;
          };
        };

        minecraft = pkgs.mkShell { packages = lib.attrValues { inherit (pkgs) packwiz; }; };
        webserver = self'.packages.webserver.devShell;
      };
    };
}