Start reworking the server for nix flakes

This removes all existing services as well, in preparation of moving
them to `podman`. These are easier to update to
virtualisation.oci-containers while retaining the "networks" through
pods.

flake.nix

@@ -0,0 +1,47 @@
+{
+  description = "tlater.net host configuration";
+
+  inputs = {
+    nixpkgs.url = "github:nixos/nixpkgs/nixos-20.09";
+    nixos-hardware.url = "github:nixos/nixos-hardware/master";
+    flake-utils.url = "github:numtide/flake-utils";
+  };
+
+  outputs = { nixpkgs, nixos-hardware, flake-utils, ... }@inputs:
+    {
+      nixosConfigurations = {
+        tlaternet = nixpkgs.lib.nixosSystem {
+          system = "x86_64-linux";
+
+          modules = [
+            (import ./configuration)
+            (import ./configuration/linode.nix)
+            (import ./configuration/hardware-configuration.nix)
+            nixpkgs.modules.headless
+          ];
+        };
+
+        vm = nixpkgs.lib.nixosSystem {
+          system = "x86_64-linux";
+
+          modules = [
+            (import ./configuration)
+            ({ ... }: {
+              users.users.tlater.password = "insecure";
+              # virtualisation.memorySize = 3941;
+              # virtualisation.cores = 2;
+            })
+          ];
+        };
+      };
+    } // flake-utils.lib.eachDefaultSystem (system: {
+      devShell = with nixpkgs.legacyPackages.${system};
+        mkShell {
+          buildInputs = [ nixfmt git-lfs ];
+          shellHook = ''
+            export QEMU_OPTS="-m 3941 -smp 2"
+            export QEMU_NET_OPTS="hostfwd=::3022-:2222,hostfwd=::3080-:80,hostfwd=::3443-:443,hostfwd=::3021-:2221,hostfwd=::25565-:25565"
+          '';
+        };
+    });
+}