nextcloud: Use a hardened systemd unit instead of a container

configuration/default.nix

@@ -9,6 +9,7 @@
     ./services/nextcloud.nix
     ./services/webserver.nix
     ./services/starbound.nix
+    ./services/postgres.nix
     ./ids.nix
     ./sops.nix
   ];
@@ -81,7 +82,6 @@
     in {
       "${domain}" = proxyPassToPort 3002 {serverAliases = ["www.${domain}"];};
       "gitea.${domain}" = proxyPassToPort 3000 {};
-      "nextcloud.${domain}" = proxyPassToPort 3001 {};
     };
   };
 

configuration/services/nextcloud.nix

@@ -1,53 +1,43 @@
-{config, ...}: {
-  virtualisation.pods.nextcloud = {
-    hostname = "nextcloud.tlater.net";
-    publish = ["3001:80"];
-    network = "slirp4netns";
+{
+  pkgs,
+  config,
+  ...
+}: let
+  inherit (pkgs) fetchNextcloudApp;
+  nextcloud = pkgs.nextcloud23;
+  hostName = "nextcloud.${config.services.nginx.domain}";
+in {
+  services.nextcloud = {
+    inherit hostName;
 
-    containers = {
-      nextcloud = {
-        image = "nextcloud:fpm-alpine";
-        dependsOn = ["postgres"];
-        volumes = [
-          "nextcloud-root:/var/www/html"
-          "nextcloud-apps:/var/www/html/custom_apps"
-          "nextcloud-config:/var/www/html/config"
-          "nextcloud-data:/var/www/html/data"
-        ];
-        environment = {
-          POSTGRES_DB = "nextcloud";
-          POSTGRES_USER = "nextcloud";
-          POSTGRES_HOST = "localhost";
-          OVERWRITEPROTOCOL = "https";
-          TRUSTED_PROXIES = "127.0.0.1";
-        };
-      };
+    package = nextcloud;
+    enable = true;
+    maxUploadSize = "2G";
+    https = true;
 
-      cron = {
-        image = "nextcloud:fpm-alpine";
-        entrypoint = "/cron.sh";
-        dependsOn = ["postgres" "nextcloud"];
-        extraOptions = ["--volumes-from=nextcloud-nextcloud"];
-      };
+    config = {
+      overwriteProtocol = "https";
 
-      nginx = {
-        image = "nginx:alpine";
-        dependsOn = ["nextcloud"];
-        volumes = [
-          "nextcloud-root:/var/www/html:ro"
-          "${./configs/nginx-nextcloud.conf}:/etc/nginx/nginx.conf:ro"
-        ];
-        extraOptions = ["--volumes-from=nextcloud-nextcloud"];
-      };
+      dbtype = "pgsql";
+      dbhost = "/run/postgresql";
 
-      postgres = {
-        image = "postgres:alpine";
-        environment = {
-          POSTGRES_DB = "nextcloud";
-          POSTGRES_USER = "nextcloud";
-        };
-        volumes = ["nextcloud-postgres-14:/var/lib/postgresql/data"];
-      };
+      adminuser = "tlater";
+      adminpassFile = config.sops.secrets."nextcloud/tlater".path;
+
+      defaultPhoneRegion = "AT";
     };
+
+    # TODO(tlater): Add redis config. This will be much easier
+    # starting with 22.11, since this will add an `extraOptions` where
+    # the necessary redis config can go.
+  };
+
+  # Ensure that this service doesn't start before postgres is ready
+  systemd.services.nextcloud-setup.after = ["postgresql.service"];
+
+  # Set up SSL
+  services.nginx.virtualHosts."${hostName}" = {
+    forceSSL = true;
+    enableACME = true;
   };
 }

configuration/services/postgres.nix

@@ -0,0 +1,30 @@
+{
+  services.postgresql = {
+    enable = true;
+
+    # Only enable connections via the unix socket, and check with the
+    # OS to make sure the user matches the database name.
+    #
+    # See https://www.postgresql.org/docs/current/auth-pg-hba-conf.html
+    authentication  = ''
+      local sameuser all peer
+    '';
+
+    # Note: The following options with ensure.* are set-only; i.e.,
+    # when permissions/users/databases are removed from these lists,
+    # that operation needs to be performed manually on the system as
+    # well.
+    ensureUsers = [
+      {
+        name = "nextcloud";
+        ensurePermissions = {
+          "DATABASE nextcloud" = "ALL PRIVILEGES";
+        };
+      }
+    ];
+
+    ensureDatabases = [
+      "nextcloud"
+    ];
+  };
+}