WIP: test: Set up service tests

checks/default.nix

@@ -6,6 +6,8 @@ let
 in
 {
   x86_64-linux = lib.mergeAttrsList [
+    flake-inputs.self.nixosConfigurations.hetzner-1.config.serviceTests
+
     {
       nix = checkLib.mkLint {
         name = "nix-lints";

configuration/default.nix

@@ -11,7 +11,7 @@
     flake-inputs.tlaternet-webserver.nixosModules.default
 
     "${modulesPath}/profiles/minimal.nix"
-    (import ../modules)
+    ../modules
 
     ./services/backups.nix
     ./services/battery-manager.nix

configuration/nginx/default.nix

@@ -1,4 +1,9 @@
-{ lib, ... }:
+{
+  flake-inputs,
+  pkgs,
+  lib,
+  ...
+}:
 {
   imports = [
     ./logging.nix
@@ -10,7 +15,8 @@
     description = "The base domain name to append to virtual domain names";
   };
 
-  config.services.nginx = {
+  config = {
+    services.nginx = {
       enable = true;
       recommendedTlsSettings = true;
       recommendedOptimisation = true;
@@ -19,4 +25,54 @@
       clientMaxBodySize = "10G";
       statusPage = true; # For metrics, should be accessible only from localhost
     };
+
+    serviceTests =
+      let
+        testHostConfig =
+          { config, ... }:
+          {
+            _module.args = { inherit flake-inputs; };
+            imports = [
+              ./.
+              ../../modules/serviceTests/mocks.nix
+              flake-inputs.sops-nix.nixosModules.sops
+            ];
+
+            services.nginx = {
+              domain = "testHost";
+
+              virtualHosts."${config.services.nginx.domain}" = {
+                useACMEHost = "tlater.net";
+                forceSSL = true;
+                enableHSTS = true;
+                locations."/".return = "200 ok";
+              };
+            };
+          };
+      in
+      {
+        hstsIsSet = pkgs.testers.runNixOSTest {
+          name = "assert-hsts";
+          nodes = {
+            testHost = testHostConfig;
+
+            client =
+              { pkgs, ... }:
+              {
+                environment.systemPackages = [ pkgs.curl ];
+              };
+          };
+
+          testScript = ''
+            start_all()
+
+            testHost.wait_for_unit("nginx")
+            testHost.succeed("systemctl start network-online.target")
+            testHost.wait_for_unit("network-online.target")
+
+            client.succeed("curl http://testHost")
+          '';
+        };
+      };
+  };
 }

modules/default.nix

@@ -1 +1,6 @@
-{ imports = [ ./crowdsec ]; }
+{
+  imports = [
+    ./crowdsec
+    ./serviceTests/stub.nix
+  ];
+}

modules/serviceTests/mocks.nix

@@ -0,0 +1,27 @@
+/**
+  Module containing mock definitions for service test runners.
+*/
+{ lib, ... }:
+{
+  imports = [
+    ../.
+    ../../configuration/services/backups.nix
+  ];
+  # imports = [ flake-inputs.sops-nix.nixosModules.sops ];
+
+  sops.defaultSopsFile = ../../keys/staging.yaml;
+  environment.etc."staging.key" = {
+    mode = "0400";
+    source = ../../keys/hosts/staging.key;
+  };
+  services.openssh = {
+    enable = true;
+    hostKeys = lib.mkForce [
+      {
+        type = "rsa";
+        bits = 4096;
+        path = "/etc/staging.key";
+      }
+    ];
+  };
+}

modules/serviceTests/stub.nix

@@ -0,0 +1,20 @@
+/**
+  Module to make writing service-specific tests easy.
+*/
+{ lib, ... }:
+let
+  inherit (lib) mkOption types;
+in
+{
+  options = {
+    serviceTests = mkOption {
+      type = types.attrsOf types.package;
+
+      description = ''
+        NixOS tests to run.
+      '';
+
+      default = { };
+    };
+  };
+}